Comment réaliser un écran de veille Windows ?

1. Un écran de veille, qu'est ce que c'est ?
2. Un exemple concret : Les balles rebondissantes
3. Notes de dernière minute

• Code source de l'écran de veille (14.2 ko)

Un écran de veille, qu'est ce que c'est ?

• Le mode Ecran de veille : C'est lorsque l'écran de veille fonctionne de façon normale, lorsque l'on clique sur le bouton 'Aperçu' ou lorsque l'on attend un certain temps.
• Le mode Configuration : Ce mode permet de configurer l'écran de veille à l'aide de la boîte de dialogue appropriée. Quand vous cliquez sur le bouton 'Configurer' des propriétés d'affichage.

Un exemple concret : Les balles rebondissantes

Public Function GetArg(Arg As Integer) As String
Dim strArg()  As String
Dim strCommand      As String
Dim strChar         As String * 1
Dim intLength       As Integer
Dim intArg          As Integer
Dim i
Dim j

strCommand = Command()
intLength = Len(strCommand)
For i = 1 To intLength
    strChar = Mid(strCommand, i, 1)
    If strChar = "/" Then
        intArg = intArg + 1
        ReDim Preserve strArg(1 To intArg)
        strArg(intArg) = strArg(intArg) & strChar
        For j = i + 1 To intLength
            strChar = Mid(strCommand, j, 1)
            If strChar = "/" Then
                strArg(intArg) = Trim(strArg(intArg))
                Exit For
            End If
            strArg(intArg) = strArg(intArg) & strChar
        Next j
    End If
Next i

If Arg <= 0 Then
    GetArg = strArg(LBound(strArg))
ElseIf Arg > UBound(strArg) Then
    GetArg = strArg(UBound(strArg))
Else
    GetArg = strArg(Arg)
End If
End Function

Public Sub Main()
If App.PrevInstance = True Then End

Select Case Left(UCase(GetArg(1)), 2)
Case "/C"
    frmConfig.Show
Case "/S"
    frmScreensaver.Show
End Select

Do
Loop Until DoEvents = 0
End Sub

Private Sub Form_Load()
With Me
    .BackColor = vbBlack
    .Move 0, 0, Screen.Width, Screen.Height
End With
End Sub

Private Sub Evénement()
Unload Me
End Sub

• Form_Click
• Form_DblClick
• Form_Deactivate
• Form_KeyDown
• Form_KeyPress
• Form_KeyUp
• Form_LostFocus
• Form_MouseDown
• Form_MouseMove (voir ci-dessous)
• Form_MouseUp

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
Static sngX     As Single
Static sngY     As Single
Static blnInit  As Boolean

If blnInit = False Then
    sngX = X
    sngY = Y
    blnInit = True
    Exit Sub
End If

If sngX + 5 < X Or sngX - 5 > X Or sngY + 5 < Y Or sngY - 5 > Y Then Unload Me

End Sub

Option Explicit

Public Const REG_SECT_BALLES    As String = "Balles"
Public Const REG_BALLES_NOMBRE  As String = "Nombre"

Public Type TBalle
    X       As Single
    Y       As Single
    CX      As Single
    CY      As Single
    Diam    As Integer
End Type

Public Balle()  As TBalle

Public Function GetNumBalles() As Integer

GetNumBalles = CInt(GetSetting(App.EXEName, REG_SECT_BALLES, REG_BALLES_NOMBRE, 1))

End Function

Private Sub tmrScreensaver_Timer()
Static blnInit  As Boolean
Dim i

If blnInit = False Then
    ReDim Balle(GetNumBalles - 1)
    FillStyle = vbFSSolid
    For i = LBound(Balle) To UBound(Balle)
        Randomize Timer
        With Balle(i)
            .X = Rnd * Screen.Width
            .Y = Rnd * Screen.Height
            .CX = Rnd * 100 * IIf(Rnd > 0.5, -1, 1)
            .CY = Rnd * 100 * IIf(Rnd > 0.5, -1, 1)
            .Diam = Rnd * 500
        End With
    Next i
    blnInit = True
End If

For i = LBound(Balle) To UBound(Balle)
    With Balle(i)
        FillColor = BackColor
        Circle (.X, .Y), .Diam, BackColor
        .X = .X + .CX
        .Y = .Y + .CY
        FillColor = vbYellow
        Circle (.X, .Y), .Diam, vbYellow
        If .X - .Diam <= ScaleLeft Or .X + .Diam >= ScaleWidth Then .CX = -.CX
        If .Y - .Diam <= ScaleTop Or .Y + .Diam >= ScaleHeight Then .CY = -.CY
    End With
Next i
End Sub

Private Sub cmdAnnuler_Click()
Unload Me
End Sub

Private Sub cmdOK_Click()
If IsNumeric(txtBalles.Text) = False Then
    MsgBox "Nommbre de balles incorrect !", vbExclamation
    Exit Sub
End If

SaveSetting App.EXEName, REG_SECT_BALLES, REG_BALLES_NOMBRE, txtBalles.Text

Unload Me
End Sub

Private Sub Form_Load()
txtBalles.Text = GetNumBalles
End Sub

Notes de dernière minute