QBasic - L'accès aux fichiers

1. Les fichiers à accès séquentiel
2. Les fichiers à accès aléatoire
3. Les fichiers binaires
4. Fonctions et instructions complémentaires
   1. FREEFILE
   2. LOF
   3. LOC
   4. SEEK

Les fichiers à accès séquentiel

OPEN "C:\Warrior.txt" FOR OUTPUT AS #1

OPEN "C:\Warrior.txt" FOR OUTPUT AS #1           ' ouverture du fichier en écriture
  PRINT #1, "Ceci est un texte dans un fichier"  ' écriture dans le fichier #1
CLOSE #1                                         ' fermeture

' Création du fichier C:\Warrior.txt avec du texte à l'intérieur
OPEN "C:\Warrior.txt" FOR OUTPUT AS #1
  PRINT #1, "Ceci est un texte dans un fichier"
CLOSE #1

' Lecture du fichier créé précédement
OPEN "C:\Warrior.txt" FOR INPUT AS #1
  INPUT #1, Texte$
CLOSE #1
PRINT "Le texte du fichier est : "; Texte$

COMMON SHARED Fichier$

Fichier$ = "C:\Notes.txt"
CLS

DO
  PRINT "[L]ire | [E]crire | [Q]uitter"
  DO
    Touche$ = UCASE$(INKEY$)
  LOOP UNTIL Touche$ <> ""
  
  SELECT CASE Touche$
  CASE "L"
    Lire
  CASE "E"
    Ecrire
  END SELECT
LOOP UNTIL Touche$ = "Q"
END

SUB Ecrire()
' Cette procédure ecrit dans le fichier
CLS
PRINT "Ecrire sautez une ligne pour finir"
PRINT

OPEN Fichier$ FOR OUTPUT AS #1
  DO
    LINE INPUT Texte$
    PRINT #1, Texte$
  LOOP UNTIL Texte$ = ""
CLOSE #1
END SUB

SUB Lire()
' Cette procédure lit le contenu du fichier et l'affiche
CLS
PRINT "*** Bloc-Notes ***"
PRINT

OPEN Fichier$ FOR INPUT AS #1
  DO UNTIL EOF(1) = -1
    LINE INPUT #1, Ligne$
    PRINT Ligne$
  LOOP
CLOSE #1
END SUB

• INKEY$ : cette instruction renvoie l'état d'une touche du clavier lors de son appelle. C'est à dire que si la touche 'T' est enfoncée, INKEY$ vaudra 'T'. Mais si la touche était 't', INKEY$ vaudrais 't'. C'est pourquoi on converti le retour de INKEY$ en lettres majuscules à l'aide de l'instruction UCASE$.
• EOF : EOF renvoi -1 (TRUE) si la fin du fichier dont le numéro lui est associé est atteinte. Le numéro est le celui entre parenthéses (ici, 1).
• LINE INPUT : on a tout simplement rajouté LINE devant INPUT. Cette associtation a pour effet de lire une ligne de 255 caractères, que ce soit sur l'écran ou dans un fichier.

• Dans la boucle DO...LOOP, on commence par afficher le menu rudimentaire.
• Ensuite l'execution du programme est suspendue jusqu'à ce que l'utilisateur appuie sur une touche.
• Puis, à l'aide d'une structure SELECT...CASE, on analyse la commande et on la traite. Si la commande est 'L' (Lire le fichier), on execute la procédure 'Lire'. Si la commande est 'E' (Ecrire dans le fichier), on execute la procédure 'Ecrire'. En revanche, si la commande est 'Q' (Quitter), on sort de la boucle, ce qui a pour effet de terminer le programme avec l'instruction END.

• Ecrire : cette procédure écrit dans le fichier définit au départ dans la variable Fichier$. Pour cela, on ouvre le fichier avec OPEN et l'accés OUTPUT, pour pouvoir écrire dedans. On lui attribut le numéro 1.
  Puis on rentre dans une boucle DO...LOOP. Cette boucle demande à l'utilisateur d'entrer du texte. Ce texte est ensuite écrit dans le fichier. Si l'utilisateur entre une ligne vierge, la boucle se termine. Le fichier est alors refermé avec l'instruction CLOSE.
• Lire : cette procédure lit le fichier et affiche le contenu sur l'écran. Le fichier est comme d'habitude ouvert avec l'instruction OPEN. Cependant, le mode d'accès différe puisqu'on utilise INPUT.
  Et comme dans la procédure détaillée précédemment, on entre dans une boucle DO...LOOP. On lit alors toute une ligne du fichier avec LINE INPUT puis on l'écrit sur l'écran avec PRINT. La boucle se termine lorsque la fin du fichier est atteinte, c'est à dire lorque EOF vaut -1 (TRUE). Puis on referme le fichier.

COMMON SHARED Fichier$

Fichier$ = "C:\Notes.txt"
CLS

DO
  PRINT "[L]ire | [E]crire | [Q]uitter"
  DO
    Touche$ = UCASE$(INKEY$)
  LOOP UNTIL Touche$ <> ""
  
  SELECT CASE Touche$
  CASE "L"
    Lire
  CASE "E"
    Ecrire
  END SELECT
LOOP UNTIL Touche$ = "Q"
END

SUB Ecrire()
' Cette procédure ecrit dans le fichier
CLS
PRINT "Ecrire sautez une ligne pour finir"
PRINT

OPEN Fichier$ FOR APPEND AS #1               ' changement du mode d'accès
  DO
    LINE INPUT Texte$
    PRINT #1, Texte$
  LOOP UNTIL Texte$ = ""
CLOSE #1
END SUB

SUB Lire()
' Cette procédure lit le contenu du fichier et l'affiche
CLS
PRINT "*** Bloc-Notes ***"
PRINT

OPEN Fichier$ FOR INPUT AS #1
  DO UNTIL EOF(1) = -1
    LINE INPUT #1, Ligne$
    PRINT Ligne$
  LOOP
CLOSE #1
END SUB

• Lors de l'ouverture d'un fichier avec les modes d'accés INPUT et APPEND, le fichier doit OBLIGATOIREMENT exister. Dans le cas contraire, une erreur 'Fichier non trouvé' se produit.
• Comme pour du texte à l'écran, on peut utiliser l'instruction PRINT USING pour écrire du texte en forme, avec le numéro du fichier après PRINT, naturellement.

Les fichiers à accès aléatoire

TYPE TClient
  Numero AS INTEGER
  Societe AS STRING * 30
  Nom AS STRING * 30
  Prenom AS STRING * 30
  Telephone AS STRING * 30
  Fax AS STRING * 30
  Email AS STRING * 30
END TYPE
COMMON SHARED Fichier$

Fichier$ = "C:\Clients.txt"

DO
  PRINT "[N]ouveau client | [A]ller à | [Q]uitter"
  DO
    Touche$ = UCASE$(INKEY$)
  LOOP UNTIL Touche$ <> ""
  SELECT CASE Touche$
  CASE "N"
    Nouveau
  CASE "A"
    Aller
  END SELECT
LOOP UNTIL Touche$ = "Q"
END

SUB Nouveau()
DIM Client AS TClient
CLS
PRINT "*** Création d'un nouveau client ***"
PRINT
INPUT "Numéro client : ", Client.Numero
INPUT "Société : ", Client.Societe
INPUT "Nom : ", Client.Nom
INPUT "Prénom : ", Client.Prenom
INPUT "Telephone : ", Client.Telephone
INPUT "Fax : ", Client.Fax
INPUT "Email : ", Client.Email

OPEN Fichier$ FOR RANDOM AS #1 LEN = LEN(Client)
  PUT #1, Client.Numero, Client
CLOSE #1
END SUB

SUB Aller()
DIM Client AS TClient
CLS
PRINT "*** Aller à un numéro de client ***"
PRINT
INPUT "Numéro du client à rechercher : ", Numero

OPEN Fichier$ FOR RANDOM AS #1 LEN = LEN(Client)
  GET #1, Numero, Client
CLOSE #1

PRINT "Société : ", Client.Societe
PRINT "Nom : ", Client.Nom
PRINT "Prénom : ", Client.Prenom
PRINT "Telephone : ", Client.Telephone
PRINT "Fax : ", Client.Fax
PRINT "Email : ", Client.Email
END SUB

OPEN Fichier$ FOR RANDOM LEN = 182

Les fichiers binaires

SCREEN 0
WIDTH 80, 50
DIM Octet AS STRING * 1
INPUT "Nom du fichier à ouvrir : ", Fichier$
CLS
OPEN Fichier$ FOR BINARY AS #1
  FOR i = 1 TO LOF(1)
    GET #1, i, Octet
    PRINT HEX$(ASC(Octet)) + SPACE$(1); 
    IF i / 4 = INT(i / 4) THEN PRINT ,
    IF i / 16 = INT(i / 16) THEN 
      FOR j = i - 15 TO i
        GET #1, j, Octet
        IF Octet < SPACE$(1) THEN Octet = SPACE$(1)
        PRINT Octet;
      NEXT j
      PRINT : PRINT
    END IF
  NEXT i
CLOSE #1

Fonctions et instructions complémentaires

FREEFILE

Num = FREEFILE                       ' FREEFILE renvoi le prochain numéro
     ' de fichier disponible
OPEN "C:\Notes.txt" FOR INPUT AS Num
CLOSE Num

LOF

OPEN "C:\Notes.txt" FOR INPUT AS #1
  PRINT "La taille du fichier est de "; LOF(1); " octets."
CLOSE #1

LOC

• Accès séquentiel : retourne la position de l'octet pointé, mais divisé par 128.
• Accès aléatoire : renvoi le numéro du dernier enregistrement lu ou écrit.
• Accès binaire : retourne la position du dernier octet lu ou écrit.

SEEK