Turbo Pascal - Les unités

1. Unités utilisateurs

• Crt : conrôle du mode vidéo, gestion des codes géographiques des touches, des fenêtres et du son.
• Dos : système d'exploitation
• Graph : fonctions graphiques (cercles, lignes...)
• Graph3 : fonctions graphiques de Turbo Pascal 3.0 : gestion de la fameuse Tortue
• Overlay : sert plus ou moins pour la gestion matérielle
• Printer : gestion du port d'impression (LPT1) à l'aide d'un fichier texte
• System : couvre la quasi-totalité des opérations d'entrée-sortie (cf. ci-dessus)
• Turbo3 : permet d'assurer la compatibilité des programmes écrit avec Turbo Pascal 3.0
• WinDos : idem à Dos, mais plus complet

Program MyProg;

Uses Crt;           { On utilise l'untité Crt }

Begin
  Repeat
    write('Appuyez sur une touche pour stopper l''écriture de ce stupide message!');
  Until KeyPressed; { On utilise KeyPressed, de l'unité Crt }
End.

Unités utilisateurs

Unit Nom    {Nom de l'unité}

Interface          {Partie "publique"}
  Uses Unité1, Unité2;

  Const Const1 : Type = Valeur;
        Const2 : Type = Valeur;

  Types Type1
        Type2

  Var Var1 : Type;
      Var2 : Type;

  Procedure Procedure1(Arg1,Arg2);       {Déclarations des procédures & fonctions}
  Function Function1(Arg1,Arg2) : Type;  {pouvant être utilisées par les programmes}

Implementation     {Partie "privée"}
  Uses Unité1, Unité2;

  Label Label1, Label2;

  Const Const1 : Type = Valeur;
        Const2 : Type = Valeur;

  Types Type1
        Type2

  Var Var1 : Type;
      Var2 : Type;

  Procedure Procedure1(Arg1,Arg2);
  Var pVar1 : Type;
      pVar2 : Type;
  Begin
    [Instructions]
  End;

  Function Function1(Arg1,Arg2) : Type;
  Var pVar1 : Type;
      pVar2 : Type;
  Begin
    [Instructions]
  End;

Begin        {Initialisation}
  [Instructions]
End.

• Unit : c'est le nom de l'unité. Contrairement au program dans un programme, Unit est obligatoire
• Interface : c'est la partie publique de l'unité. C'est à dire que toutes les constantes, types, variables, procédures et fonctions seront accessibles par le programme utilisateur.
  En ce qui concerne les procédures et les fonctions, il ne faut spécifier que leurs déclarations, les procédures et fonctions proprements dites étant écrites dans la partie Implementation
• Implementation : c'est la partie privée. Les constantes, types, variables, procédures et fonctions ne sont utilisables que par l'unité elle même, à part les procédures et fonctions déclarées dans la partie Interface.
• begin...end. : comme pour un programme, c'est le coeur de l'unité. Ça peut paraitre étrange, puiqu'une unité n'a pas pour vocation d'être executée. En fait, cette partie sert surtout pour une éventuelle initialisation de divers paramêtres.
  Même si vous n'avez pas prévu une telle étape, vous devez quand même l'inclure.

unit Electro;

Interface
  Const PermAir : Real = 1;           {Perméabilité relative}
        PermFer : Real = 2500;
        PermNickel : Real = 250000;
        PermVide : Real = Pi * 4E-7;

        ChargElec : Real = -1.6E-19;  {Charge électron}

  Function Puissance(U, I : Real) : Real;     {Puissance}
  Function EnergiePT(P, T : Real) : Real;     {Energie en fonction de la puissance
       et du temps}
  Function EnergieUIT(U, I, T : Real) : Real; {Energie en fonction de U, I et T }

Implementation
  Function Puissance(U, I : Real) : Real;
  begin
    Puissance := U * I;
  end;

  Function EnergiePT(P, T : Real) : Real;
  begin
    EnergiePT := P * T;
  end;

  Function EnergieUIT(U, I, T : Real) : Real;
  begin
    {On fait appel aux fonctions déjà établies }
    EnergieUIT := EnergiePT(Puissance(U, I), T);
  end;

begin
  {Pas d'initialisation}
end.

Program TestUnit;

Uses Electro;

Var U : Real;
    I : Real;
    t : Real;

Begin
  writeln('*** Calcul de l''énergie électrique avec l''unité ELECTRO ***');
  write('U (en volts)    = ');
  readln(U);
  write('I (en ampères)  = ');
  readln(I);
  write('t (en secondes) = ');
  readln(t);
  writeln('La puissance dissipée est de ', EnergieUIT(U, I, t), ' joules.');
End.